Windows SharePoint Services 3.0: справка и инструкции

Примеры часто используемых формул

Следующие примеры можно использовать в вычисляемых столбцах списка или библиотеки. Примеры, не содержащие ссылок на столбцы, могут применяться для задания значения столбца по умолчанию.

В этой статье

ссылка на закладку Условные формулы

ссылка на закладку Формулы для работы со значениями даты и времени

ссылка на закладку Математические формулы

ссылка на закладку Формулы для работы с текстом

Условные формулы

Следующие формулы возвращают значение «Да» или «Нет» и могут использоваться для проверки условия в выражении, например для проверки значения «ОК» или «Неверно». Они также могут возвращать пустое значение или тире.

Показать Сравнение чисел

Для выполнения этой задачи используется функция ЕСЛИ.

Столбец1	Столбец2	Формула	Описание (возможный результат)
15000	9000	=[Столбец1]>[Столбец2]	Столбец1 больше, чем Столбец2? (Да)
15000	9000	=ЕСЛИ([Столбец1]<=[Столбец2]; "ОК"; "Неверно")	Столбец1 меньше или равен Столбец2? (Неверно)

Показать Возврат логического значения после сравнения содержимого столбцов

Для результата, являющегося логическим значением («Да» или «Нет») используйте функции И, ИЛИ и НЕ.

Столбец1	Столбец2	Столбец3	Формула	Описание (возможный результат)
15	9	8	=И([Столбец1]>[Столбец2]; [Столбец1]<[Столбец3])	15 больше 9 и меньше 8? (Нет)
15	9	8	=ИЛИ([Столбец1]>[Столбец2]; [Столбец1]<[Столбец3])	15 больше 9 или меньше 8? (Да)
15	9	8	=НЕ([Столбец1]+[Столбец2]=24)	15 плюс 9 не равно 24? (Нет)

Для результата, являющегося другим вычислением или любым значением, кроме «Да» или «Нет», используйте функции ЕСЛИ, И и ИЛИ.

Столбец1	Столбец2	Столбец3	Формула	Описание (возможный результат)
15	9	8	=ЕСЛИ([Столбец1]=15; "ОК"; "Неверно")	Если значение в Столбец1 равно 15, возвращается «ОК». (ОК)
15	9	8	=ЕСЛИ(И([Столбец1]>[Столбец2]; [Столбец1]<[Столбец3]); "ОК"; "Неверно")	Если 15 больше 9 и меньше 8, возвращается «ОК». (Неверно)
15	9	8	=ЕСЛИ(ИЛИ([Столбец1]>[Столбец2]; [Столбец1]<[Столбец3]); "ОК"; "Неверно")	Если 15 больше 9 или меньше 8, возвращается «ОК». (ОК)

Показать Отображение нулей в виде пробелов или тире

Чтобы отобразить ноль, выполните простое вычисление. Чтобы отобразить пробел или тире, используйте функцию ЕСЛИ.

Столбец1	Столбец2	Формула	Описание (возможный результат)
10	10	=[Столбец1]-[Столбец2]	Из первого (0) номера вычтен второй
15	9	=ЕСЛИ([Столбец1]-[Столбец2]; "-"; [Столбец1]-[Столбец2])	Возвращает «-», если ячейка содержит нулевые значения.

Показать Скрытие значений ошибок в столбцах

Чтобы отобразить тире, #Н/Д или НД вместо значения ошибки, воспользуйтесь функцией ЕОШИБКА.

Столбец1	Формула	Описание (возможный результат)
10	=[Столбец1]/[Столбец2]	Ошибка #ДЕЛ/0!
10	=ЕСЛИ(ЕОШИБКА([Столбец1]/[Столбец2]); "НД"; [Столбец1]/[Столбец2])	Возвращает «НД», если ячейка содержит значение ошибки.
10	=ЕСЛИ(ЕОШИБКА([Столбец1]/[Столбец2]); "-"; [Столбец1]/[Столбец2])	Возвращает «-», если ячейка содержит значение ошибки.

К началу страницы

Формулы для работы со значениями даты и времени

С помощью следующих формул можно производить вычисления со значениями даты и времени, например прибавить к дате число дней, месяцев или лет, вычислить разность между двумя датами и преобразовать время в десятичное значение.

Показать Сложение дат

Чтобы прибавить к дате число дней, воспользуйтесь оператором сложения (+).

Примечание. При вычислениях с датами тип возвращаемого значения вычисляемого столбца должен быть установлен как Дата и время.

Столбец1	Столбец2	Формула	Описание (результат)
9.6.2007	3	=[Столбец1]+[Столбец2]	Прибавление 3 дней к 09.06.07 (12.06.07)
10.12.2008	54	=[Столбец1]+[Столбец2]	Прибавление 54 дней к 10.12.08 (02.02.09)

Чтобы прибавить к дате число месяцев, воспользуйтесь функциями ДАТА, ГОД, МЕСЯЦ и ДЕНЬ.

Столбец1	Столбец2	Формула	Описание (результат)
9.6. 2007	3	=ДАТА(ГОД([Столбец1]); МЕСЯЦ([Столбец1])+[Столбец2]; ДЕНЬ([Столбец1]))	Прибавление 3 месяцев к 09.06.07 (09.09.07)
10.12.2008	25	=ДАТА(ГОД([Столбец1]); МЕСЯЦ([Столбец1])+[Столбец2]; ДЕНЬ([Столбец1]))	Прибавление 25 месяцев к 10.12.08 (10.01.11)

Чтобы прибавить к дате число лет, воспользуйтесь функциями ДАТА, ГОД, МЕСЯЦ и ДЕНЬ.

Столбец1	Столбец2	Формула	Описание (результат)
9.6.2007	3	=ДАТА(ГОД([Столбец1])+[Столбец2]; МЕСЯЦ([Столбец1]); ДЕНЬ([Столбец1]))	Прибавление 3 лет к 09.06.07 (09.06.10)
10.12.2008	25	=ДАТА(ГОД([Столбец1])+[Столбец2]; МЕСЯЦ([Столбец1]); ДЕНЬ([Столбец1]))	Прибавление 25 лет к 10.12.08 (10.12.33)

Чтобы прибавить к дате комбинацию из дней, месяцев и лет, воспользуйтесь функциями ДАТА, ГОД, МЕСЯЦ и ДЕНЬ.

Столбец1	Формула	Описание (результат)
9.6.2007	=ДАТА(ГОД([Столбец1])+3; МЕСЯЦ([Столбец1])+1; ДЕНЬ([Столбец1])+5)	Прибавление 3 лет, 1 месяца и 5 дней к 09.06.2007 (14.07.10)
10.12.2008	=ДАТА(ГОД([Столбец1])+1; МЕСЯЦ([Столбец1])+7; ДЕНЬ([Столбец1])+5)	Прибавление 1 года, 7 месяцев и 5 дней к 10.12.08 (15.07.10)

Показать Вычисление разницы между двумя датами

Для выполнения этой задачи используется функция РАЗНДАТ.

Столбец1	Столбец2	Формула	Описание (результат)
01-Янв-1995	15-Июн-1999	=РАЗНДАТ([Столбец1]; [Столбец2]; "д")	Возвращает количество дней между двумя датами (1626)
01-Янв-1995	15-Июн-1999	=РАЗНДАТ([Столбец1]; [Столбец2]; "гм")	Возвращает количество месяцев между датами, игнорируя годы (5)
01-Янв-1995	15-Июн-1999	=РАЗНДАТ([Столбец1]; [Столбец2]; "гд")	Возвращает количество дней между датами, игнорируя годы (165)

Показать Вычисление разницы во времени

Для представления результата в стандартном формате времени (часы : минуты : секунды) воспользуйтесь оператором вычитания (-) и функцией ТЕКСТ. Чтобы этот метод работал, количество часов не должно превышать 24, а количество минут и секунд не должно превышать 60.

Столбец1	Столбец2	Формула	Описание (результат)
09.06.07 10:35:00	09.06.07 15:30	=ТЕКСТ([Столбец1]- [Столбец2]; "ч")	Количество часов между двумя значениями времени (4)
09.06.07 10:35:00	09.06.07 15:30	=ТЕКСТ([Столбец1]- [Столбец2]; "ч:мм")	Количество часов и минут между двумя значениями времени (4:55)
09.06.07 10:35:00	09.06.07 15:30	=ТЕКСТ([Столбец1]- [Столбец2]; "ч:мм:сс")	Количество часов, минут и секунд между двумя значениями времени (4:55:00)

Для отображения результата в виде общего количества единиц времени, воспользуйтесь функцией ЦЕЛОЕ или функциями ЧАС, МИНУТЫ и СЕКУНДЫ.

Столбец1	Столбец2	Формула	Описание (результат)
09.06.07 10:35:00	10.06.07 15:30	=ЦЕЛОЕ([Столбец1]- [Столбец2]*24)	Общее количество часов между двумя значениями времени (28)
09.06.07 10:35:00	10.06.07 15:30	=ЦЕЛОЕ([Столбец1]- [Столбец2]*1440)	Общее количество минут между двумя значениями времени (1735)
09.06.07 10:35:00	10.06.07 15:30	=ЦЕЛОЕ([Столбец1]- [Столбец2]*86400)	Общее количество секунд между двумя значениями времени (104100)
09.06.07 10:35:00	10.06.07 15:30	=ЧАС([Столбец1]- [Столбец2])	Количество часов между двумя значениями времени, если разница не превышает 24 (4)
09.06.07 10:35:00	10.06.07 15:30	=МИНУТЫ([Столбец1]- [Столбец2])	Количество минут между двумя значениями времени, если разница не превышает 60 (55)
09.06.07 10:35:00	10.06.07 15:30	=СЕКУНДЫ([Столбец1]- [Столбец2])	Количество секунд между двумя значениями времени, если разница не превышает 60 (0)

Показать Преобразование времени

Для преобразования часов из стандартного формата времени в десятичное число воспользуйтесь функцией ЦЕЛОЕ.

Столбец1	Формула	Описание (результат)
10:35:00	=([Столбец1]- ЦЕЛОЕ([Столбец2]))*24	Число часов с 0:00:00 (10,583333)
12:15:00	=([Столбец1]- ЦЕЛОЕ([Столбец2]))*24	Число часов с 0:00:00 (12,25)

Для преобразования результата в стандартный формат времени (часы : минуты : секунды) воспользуйтесь оператором вычитания (-) и функцией ТЕКСТ.

Столбец1	Формула	Описание (результат)
23:58:00	=ТЕКСТ(Столбец1/24;"ч:мм:сс")	Количество часов, минут и секунд с 0:00:00 (00:59:55)
02:06:00	=ТЕКСТ(Столбец1/24; "ч:мм")	Часов и минут с 0:00:00 (00:05:00)

Показать Вставка дат в юлианском представлении

Выражение «Юлианское представление дат» иногда используется для обозначения формата даты, в котором после текущего года стоит номер дня с начала года. Например, дате 1 января 2007 г. соответствует значение 2007001, а 31 декабря 2007 г. — значение 2007365. Следует помнить, что этот формат не основан на юлианском календаре.

Для преобразования даты в юлианское представление воспользуйтесь функциями ТЕКСТ и ДАТАЗНАЧ.

Столбец1	Формула	Описание (результат)
23.6.2007	=ТЕКСТ([Столбец1];"гг")&ТЕКСТ(([Столбец1]-ДАТАЗНАЧ("1.1."&ТЕКСТ([Столбец1];"гг"))+1);"000")	Дата в юлианском представлении с двузначным обозначением года (07174)
23.6.2007	=ТЕКСТ([Столбец1];"гггг")&ТЕКСТ(([Столбец1]-ДАТАЗНАЧ("1.1."&ТЕКСТ([Столбец1];"гг"))+1);"000")	Дата в юлианском представлении с четырехзначным обозначением года (2007174)

Чтобы преобразовать дату в юлианское представление, применяемое в астрономии, воспользуйтесь константой 2415018.50. Эта формула работает только с датами после 01.03.1901, если используется система отсчета дат с 1900 года.

Столбец1	Формула	Описание (результат)
23.6.2007	=[Столбец1]+2415018.50	Дата в юлианском представлении, используемом в астрономии (2454274,50)

Показать Отображение дат в виде дней недели

Для преобразования дат в текстовое представление дней недели воспользуйтесь функциями ТЕКСТ и ДЕНЬНЕД.

Столбец1	Формула	Описание (возможный результат)
19-Фев-2007	=ТЕКСТ(ДЕНЬНЕД([Столбец1]);"дддд")	Вычисление дня недели для указанной даты и возврат его полного названия (понедельник)
3-Янв-2008	=ТЕКСТ(ДЕНЬНЕД([Столбец1]);"ддд")	Вычисление дня недели для указанной даты и возврат его сокращенного названия (Пн)

К началу страницы

Математические формулы

С помощью следующих формул можно производить различные математические вычисления, например складывать, вычитать, перемножать и делить числа, вычислять среднее значение или медиану, округлять числа и подсчитывать количество значений.

Показать Сложение чисел

Чтобы сложить числа в нескольких столбцах, воспользуйтесь оператором сложения (+) или функцией СУММ.

Столбец1	Столбец2	Столбец3	Формула	Описание (результат)
6	5	4	=[Столбец1]+[Столбец2]+[Столбец3]	Сложение чисел в первых трех столбцах (15)
6	5	4	=СУММ([Столбец1]; [Столбец2]; [Столбец3])	Сложение чисел в первых трех столбцах (15)
6	5	4	=СУММ(ЕСЛИ([Столбец1]>[Столбец2]; [Столбец1]-[Столбец2]; 10); [Столбец3])	Если Столбец1 больше, чем Столбец2, прибавить их разность к Столбец3. В противном случае прибавить 10 к Столбец3 (5)

Показать Вычитание чисел

Чтобы вычесть числа в нескольких столбцах, воспользуйтесь оператором вычитания (-) или функцией СУММ с отрицательными числами.

Столбец1	Столбец2	Столбец3	Формула	Описание (результат)
15000	9000	-8000	=[Столбец1]-[Столбец2]	Вычитание 9000 из 15000 (6000)
15000	9000	-8000	=СУММ([Столбец1]; [Столбец2]; [Столбец3])	Сложение чисел в первых трех столбцах, включая отрицательные значения (16000)

Показать Вычисление разницы между двумя числами в виде процентного отношения

Для выполнения этой задачи используются операторы вычитания (-) и деления (/), а также функция ABS.

Столбец1	Столбец2	Формула	Описание (результат)
2342	2500	=([Столбец2]-[Столбец1])/ABS([Столбец1])	Изменение в процентах (6,75% или 0,06746)

Показать Умножение чисел

Чтобы перемножить числа в нескольких столбцах, воспользуйтесь оператором умножения (*) или функцией ПРОИЗВЕД.

Столбец1	Столбец2	Формула	Описание (результат)
5	2	=[Столбец1]*[Столбец2]	Перемножение чисел в первых двух столбцах (10)
5	2	=ПРОИЗВЕД([Столбец1]; [Столбец2])	Перемножение чисел в первых двух столбцах (10)
5	2	=ПРОИЗВЕД([Столбец1]; [Столбец2]; 2)	Перемножение чисел в первых двух столбцах и числа 2 (20)

Показать Деление чисел

Чтобы разделить числа в нескольких столбцах, воспользуйтесь оператором деления (/).

Столбец1	Столбец2	Формула	Описание (результат)
15000	12	=[Столбец1]/[Столбец2]	Деление 15000 на 12 (1250)
15000	12	=([Столбец1]+10000)/[Столбец2]	Сложить 15000 и 10000 и разделить результат на 12 (2083)

Показать Вычисление среднего значения

Среднее значение также называется просто средним. Чтобы вычислить среднее значение чисел в нескольких столбцах, воспользуйтесь функцией СРЗНАЧ.

Столбец1	Столбец2	Столбец3	Формула	Описание (результат)
6	5	4	=СРЗНАЧ([Столбец1]; [Столбец2]; [Столбец3])	Среднее значение чисел в первых трех столбцах (5)
6	5	4	=СРЗНАЧ(ЕСЛИ([Столбец1]>[Столбец2]; [Столбец1]-[Столбец2]; 10); [Столбец3])	Если Столбец1 больше, чем Столбец2, вычислить среднее значение их разности и Столбец3. В противном случае вычислить среднее числа 10 и Столбец3 (2,5)

Показать Вычисление медианы

Медиана представляет собой значение середины упорядоченного множества чисел. Для вычисления медианы набора чисел воспользуйтесь функцией МЕДИАНА.

A	B	C	D	E	F	Формула	Описание (результат)
10	7	9	27	0	4	=МЕДИАНА(A; B; C; D; E; F)	Медиана чисел в первых 6 столбцах (8)

Показать Поиск наименьшего или наибольшего числа в диапазоне

Чтобы найти наименьшее или наибольшее число в нескольких столбцах, воспользуйтесь функциями МИН и МАКС.

Столбец1	Столбец2	Столбец3	Формула	Описание (результат)
10	7	9	=МИН([Столбец1]; [Столбец2]; [Столбец3])	Наименьшее число (7)
10	7	9	=МАКС([Столбец1]; [Столбец2]; [Столбец3])	Наибольшее число (10)

Показать Подсчет количества значений

Для подсчета количества числовых значений используется функция СЧЕТ.

Столбец1	Столбец2	Столбец3	Формула	Описание (результат)
Яблоко		12.12.2007	=СЧЕТ([Столбец1]; [Столбец2]; [Столбец3])	Подсчет количества столбцов, содержащих числовые значения. Исключаются значения даты и времени, текст и пустые значения (0)
450р.	#ДЕЛ/0!	1,01	=СЧЕТ([Столбец1]; [Столбец2]; [Столбец3])	Подсчитываются количества столбцов, содержащих числовые значения, но исключаются ошибки и логические значения (2)

Показать Увеличение или уменьшение числа на заданное количество процентов

Для выполнения этой задачи используется оператор процента (%).

Столбец1	Столбец2	Формула	Описание (результат)
23	3%	=[Столбец1]*(1+5%)	Увеличение числа в Столбец1 на 5% (24,15)
23	3%	=[Столбец1]*(1+[Столбец2])	Увеличение числа в Столбец1 на процентное значение, содержащееся в Столбец2: 3% (23.69)
23	3%	=[Столбец1]*(1-[Столбец2])	Уменьшение числа в Столбец1 на процентное значение, содержащееся в Столбец2: 3% (22,31)

Показать Возведение числа в степень

Для выполнения этой задачи используется оператор возведения в степень (^) или функция СТЕПЕНЬ.

Столбец1	Столбец2	Формула	Описание (результат)
5	2	=[Столбец1]^[Столбец2]	Возведение числа 5 в квадрат (25)
5	3	=СТЕПЕНЬ([Столбец1]; [Столбец2])	Возведение числа 5 в куб (125)

Показать Округление числа

Для округления чисел в верхнюю сторону используются функции ОКРУГЛВВЕРХ, ЧЁТН и НЕЧЁТ.

Столбец1	Формула	Описание (результат)
20,3	=ОКРУГЛВВЕРХ([Столбец1]; 0)	Округление числа 20,3 до ближайшего целого (21)
-5,9	=ОКРУГЛВВЕРХ([Столбец1]; 0)	Округление числа -5,9 вверх до ближайшего целого (-5)
12,5493	=ОКРУГЛВВЕРХ([Столбец1]; 2)	Округление числа 12,5493 до второго знака после запятой (12,55)
20,3	=ЧЕТН([Столбец1])	Округление числа 20,3 до ближайшего четного (22)
20,3	=НЕЧЕТ([Столбец1])	Округление числа 20,3 до ближайшего нечетного (21)

Для округления чисел в нижнюю сторону используется функция ОКРУГЛВНИЗ.

Столбец1	Формула	Описание (результат)
20,3	=ОКРУГЛВНИЗ([Столбец1]; 0)	Округление числа 20,3 вниз до ближайшего целого (20)
-5,9	=ОКРУГЛВНИЗ([Столбец1]; 0)	Округление числа -5,9 вниз до ближайшего целого (-6)
12,5493	=ОКРУГЛВНИЗ([Столбец1]; 2)	Округление числа 12,5493 до второго знака после запятой (12,54)

Для округления числа до ближайшего целого числа или дроби, воспользуйтесь функцией ОКРУГЛ.

Столбец1	Формула	Описание (результат)
20,3	=ОКРУГЛ([Столбец1]; 0)	Округление числа 20,3 вниз, так как дробная часть меньше 0,5 (20)
5,9	=ОКРУГЛ([Столбец1]; 0)	Округление числа 5,9 вверх, так как дробная часть больше 0,5 (6)
-5,9	=ОКРУГЛ([Столбец1]; 0)	Округление числа -5,9 вниз, так как дробная часть меньше 0,5 (-6)
1,25	=ОКРУГЛ([Столбец1]; 1)	Округление числа до одного знака после запятой. Поскольку округляемая часть — 0,05 или больше, число округляется вверх (результат: 1,3)
30,452	=ОКРУГЛ([Столбец2]; 2)	Округление числа до двух знаков после запятой. Поскольку округляемая часть (0,002) меньше 0,005, число округляется вниз (результат: 30,45)

Для округления числа до значащей цифры воспользуйтесь функциями ОКРУГЛ, ОКРУГЛВВЕРХ, ОКРУГЛВНИЗ, ЦЕЛОЕ и ДЛСТР.

Столбец1	Формула	Описание (результат)
5492820	=ОКРУГЛ([Столбец1];3-ДЛСТР(ЦЕЛОЕ([Столбец1])))	Округление числа до 3 значащих цифр (5490000)
22230	=ОКРУГЛВНИЗ([Столбец1];3-ДЛСТР(ЦЕЛОЕ([Столбец1])))	Округление числа вниз до 3 значащих разрядов (22200)
5492820	=ОКРУГЛВВЕРХ([Столбец1];5-ДЛСТР(ЦЕЛОЕ([Столбец1])))	Округление числа вверх до 5 значащих разрядов (5492900)

К началу страницы

Формулы для работы с текстом

С помощью следующих формул можно работать с текстом, например объединять строки из нескольких столбцов, сравнивать содержимое столбцов, удалять символы или пробелы, а также повторять символы.

Показать Изменение регистра текста

Для изменения регистра текста используются функции ПРОПИСН, СТРОЧН, ПРОПНАЧ.

Столбец1	Формула	Описание (результат)
дарья Попкова	=ПРОПИСН([Столбец1])	Преобразование текста в верхний регистр (ДАРЬЯ ПОПКОВА)
дарья Попкова	=СТРОЧН([Столбец1])	Преобразование текста в нижний регистр (дарья попкова)
дарья Попкова	=ПРОПНАЧ([Столбец1])	Преобразование первых букв в прописные, а всех остальных — в строчные (Дарья Попкова)

Показать Объединение имени и фамилии

Для объединения имени и фамилии используется оператор & (амперсанд) или функция СЦЕПИТЬ.

Столбец1	Столбец2	Формула	Описание (результат)
Дмитрий	Горноженко	=[Столбец1]&[Столбец2]	Объединение двух строк (ДмитрийГорноженко)
Дмитрий	Горноженко	=[Столбец1]&" "&[Столбец2]	Объединение двух строк, разделенных пробелом (Дмитрий Горноженко)
Дмитрий	Горноженко	=[Столбец2]&", "&[Столбец1]	Объединение двух строк, разделенных запятой и пробелом (Горноженко, Дмитрий)
Дмитрий	Горноженко	=СЦЕПИТЬ([Столбец2]; ","; [Столбец1])	Объединение двух строк, разделенных запятой (Горноженко,Дмитрий)

Показать Объединение текста и чисел из разных столбцов

Для объединения текста и чисел используется функция СЦЕПИТЬ, оператор & (амперсанд) или функция ТЕКСТ и оператор &.

Столбец1	Столбец2	Формула	Описание (результат)
Орехов	28	=[Столбец1]&" продал "&[Столбец2]&" единиц товара."	Объединение содержимого ячеек в одну фразу (Орехов продал 28 единиц товара.)
Корепин	40%	=[Столбец1]&" продал "&ТЕКСТ([Столбец2],"0%")&" от общего объема."	Объединение вышеприведенного содержимого в одну фразу (Корепин продал 40% от общего объема). Примечание. Функция ТЕКСТ дополняет к строке отформатированное значение Столбец2 вместо исходного значения (0,4).
Орехов	28	=СЦЕПИТЬ([Столбец1]," продал ",[Столбец2]," единиц товара.")	Объединение содержимого ячеек в одну фразу (Орехов продал 28 единиц товара.)

Показать Объединение текста с датой или временем

Для объединения текста с датой или временем используются функция ТЕКСТ и оператор & (амперсанд).

Столбец1	Столбец2	Формула	Описание (результат)
Дата выставления счета:	5-июн-2007	="Дата подачи заявления: "&ТЕКСТ([Столбец2], "Д-МММ-ГГГГ")	Объединение текста с датой (Дата подачи заявления: 5-июн-2007)
Дата выставления счета:	18 октября 2004 г.	=[Столбец1]&" "&ТЕКСТ([Столбец2], "ДД-МММ-ГГГГ")	Объединение текста и даты из разных столбцов в одном столбце (Дата выставления счета: 05-июн-2007)

Показать Сравнение содержимого столбцов

Для сравнения двух столбцов или списка значений используются функции СОВПАД и ИЛИ.

Столбец1	Столбец2	Формула	Описание (возможный результат)
БД122	БД123	=СОВПАД([Столбец1]; [Столбец2])	Сравнение содержимого левых двух столбцов (Нет)
БД122	БД123	=СОВПАД([Столбец1]; "БД122")	Сравнение содержимого Столбец1 и строки "БД122" (Да)

Показать Поиск определенного текста в столбце

Чтобы проверить, совпадает ли значение столбца или его части с определенным текстом, воспользуйтесь функциями ЕСЛИ, НАЙТИ, ПОИСК и ЕЧИСЛО.

Столбец1	Формула	Описание (возможный результат)
Попкова	=ЕСЛИ([Столбец1]="Попкова"; "ОК"; "Неверно")	Проверка равенства значения Столбец1 Попкова (ОК)
Попкова	=ЕСЛИ(ЕЧИСЛО(НАЙТИ("п";[Столбец1]));"Верно"; "Неверно")	Проверка значения Столбец1 на наличие буквы «п» (Верно)
БД123	=ЕЧИСЛО(НАЙТИ("БД";[Столбец1]))	Проверка, содержит ли Столбец1 БД (Да)

Показать Подсчет непустых столбцов

Для подсчета числа непустых столбцов используется функция СЧЕТЗ.

Столбец1	Столбец2	Столбец3	Формула	Описание (результат)
Продажи	19		=СЧЕТЗ([Столбец1]; [Столбец2])	Подсчет числа непустых столбцов (2)
Продажи	19		=СЧЕТЗ([Столбец1]; [Столбец2]; [Столбец3])	Подсчет числа непустых столбцов (2)

Показать Удаление отдельных знаков из текста

Для удаления отдельных знаков из текста используются функции ДЛСТР, ЛЕВСИМВ и ПРАВСИМВ.

Столбец1	Формула	Описание (результат)
Витамин A	=ЛЕВСИМВ([Столбец1]; ДЛСТР([Столбец1])-2)	Возвращает 7 (9-2) левых символов (Витамин)
Витамин B1	=ПРАВСИМВ([Столбец1]; ДЛСТР([Столбец1])-8)	Возвращает 2 (10-8) правых символа (В1)

Показать Удаление пробелов в начале или в конце строки в столбце

Для удаления пробелов из столбца воспользуйтесь функцией СЖПРОБЕЛЫ.

Столбец1	Формула	Описание (результат)
Привет!	=СЖПРОБЕЛЫ([Столбец1])	Удаление пробелов в начале и в конце строки (Привет!)

Показать Повторение знака в столбце

Для повторения знака в столбце используется функция ПОВТОР.

Формула	Описание (результат)
=ПОВТОР("."; 3)	Повторение точки (.) 3 раза (...)
=ПОВТОР("-";10)	Повторение тире (-) 10 раз (----------)

К началу страницы